| Pages: [1] :: one page |
| Author |
Thread Statistics | Show CCP posts - 0 post(s) |
Caliera
   |
Posted - 2007.06.20 18:15:00 -
[1]
okay guys, so here it is.
First of all You need this: Junction Tool !
Copy the junction.exe to Your EVE folder, now copy and paste the following two batch files to a notepad (or any other editor):
---------Junctions Set -------------!snip ---------
@ECHO OFF
COLOR 1F
FOR /F "tokens=2*" %%A IN ('REG QUERY "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v Personal') DO SET mdpath=%%B
FOR /F "tokens=3*" %%A IN ('REG QUERY "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "Local AppData"') DO SET ladpath=%%B
SET currdir=
IF NOT EXIST "eve.exe" GOTO ene_error
IF NOT EXIST "junction.exe" GOTO jun_error
ECHO.
ECHO EVE RevII Junction Creator for WinXP
ECHO ------------------------------------
ECHO.
ECHO Please make sure the following paths are correct !
ECHO.
ECHO Junction.exe (by SysInternals) can be downloaded from:
ECHO http://www.microsoft.com/technet/sysinternals/FileAndDisk/Junction.mspx
ECHO.
ECHO Using the following paths:
ECHO.
ECHO My Documents = %mdpath%
ECHO Local AppData = %ladpath%
ECHO EVE Path = %cd%
ECHO.
ECHO Creating Junctions...
IF NOT EXIST "%mdpath%"\EVE\capture MD "%mdpath%"\EVE\capture
IF NOT EXIST "%mdpath%"\EVE\logs MD "%mdpath%"\EVE\logs
IF NOT EXIST "%ladpath%"\CCP\EVE\cache MD "%ladpath%"\CCP\EVE\cache
IF NOT EXIST "%ladpath%"\CCP\EVE\settings MD "%ladpath%"\CCP\EVE\settings
IF NOT EXIST "%cd%"\capture MD "%cd%"\capture
IF NOT EXIST "%cd%"\cache MD "%cd%"\cache
IF NOT EXIST "%cd%"\cache\settings MD "%cd%"\cache\settings
rem XCOPY /E /H "%mdpath%"\EVE\capture "%cd%"\capture
rem XCOPY /E /H "%mdpath%"\EVE\capture\logs "%cd%"\capture
rem XCOPY /E /H "%ladpath%"\CCP\EVE\cache "%cd%"\cache
rem XCOPY /E /H "%ladpath%"\CCP\EVE\settings "%cd%"\cache\settings
junction "%mdpath%"\EVE\capture "%cd%"\capture >nul
junction "%mdpath%"\EVE\logs "%cd%"\capture >nul
junction "%ladpath%"\CCP\EVE\cache "%cd%"\cache >nul
junction "%ladpath%"\CCP\EVE\settings "%cd%"\cache\settings >nul
ECHO.
ECHO Done...
GOTO end
:ene_error
ECHO.
ECHO EVE.exe not found ! Please copy this batchfile to Your EVE folder !
GOTO end
:jun_error
ECHO.
ECHO junction.exe not found ! Please copy the tool to Your EVE folder !
GOTO end
:end
ECHO.
PAUSE
---------Junctions Set -------------!snip ---------
---------Junctions Remove -------------!snip ---------
@ECHO OFF
COLOR 1F
FOR /F "tokens=2*" %%A IN ('REG QUERY "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v Personal') DO SET mdpath=%%B
FOR /F "tokens=3*" %%A IN ('REG QUERY "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "Local AppData"') DO SET ladpath=%%B
SET currdir=
IF NOT EXIST "eve.exe" GOTO ene_error
IF NOT EXIST "junction.exe" GOTO jun_error
ECHO.
ECHO EVE RevII Junction Remover for WinXP
ECHO ------------------------------------
ECHO.
ECHO Please check the following paths to be correct !
ECHO Junction.exe (by SysInternals) can be downloaded from:
ECHO http://www.microsoft.com/technet/sysinternals/FileAndDisk/Junction.mspx
ECHO.
ECHO Using the following paths:
ECHO.
ECHO My Documents = %mdpath%
ECHO Local AppData = %ladpath%
ECHO EVE Path = %cd%
ECHO.
ECHO Removing Junctions:
junction -d "%mdpath%"\EVE\capture >nul
junction -d "%mdpath%"\EVE\logs >nul
junction -d "%ladpath%"\CCP\EVE\cache >nul
junction -d "%ladpath%"\CCP\EVE\settings >nul
ECHO.
ECHO Done...
GOTO end
:ene_error
ECHO.
ECHO EVE.exe not found ! Please copy this batch to Your EVE folder !
GOTO end
:jun_error
ECHO.
ECHO junction.exe not found ! Please copy the tool to Your EVE folder !
GOTO end
:end
ECHO.
pause
---------Junctions Remove -------------!snip ---------
Save those two as Rev2junctions_Add.cmd and Rev2junctions_Remove.cmd in Your EVE folder aswell.
continued in next post !
|
Caliera
|
Posted - 2007.06.20 18:18:00 -
[2]
Now make sure You copy the files cluttered on Your C Drive back to where they were before Revelations 2. Since i have a german windows it will look at a little different on Your english but You'll get the folder locations nevertheless:
C:\Dokumente und Einstellungen\{username}\Lokale Einstellungen\Anwendungsdaten\CCP\EVE\cache
goes to
{EVE-folder}\cache
|
Caliera
|
Posted - 2007.06.21 09:58:00 -
[3]
Oh and BTW, the only things You loose are the window positions. The bookmarks, notes, custom UI colors You set pre Rev2 are all there. To remove the junctions (in case You dont need them anymore) run the Rev2junctions_Remove.cmd.
Comments ? Suggestions ? Remarks ?
|
Raindrop
VIRTUAL LIFE VANGUARD
Freelancer Alliance
|
Posted - 2007.06.21 11:02:00 -
[4]
Looks cool for 1 account.
But with 2 accounts it looks like all data is written to one Eve folder?
Raindrop
It only takes a raindrop to cool the market.
100% Carebear and loving it.
Trader.
Hauler.
|
Caliera
|
Posted - 2007.06.21 11:10:00 -
[5]
Well You could merge the two batchfiles modify them as needed and run EVE from it. Have a look:
* set the junctions before eve client launches
* run eve from inside the batchfile
* remove the junctions after eve client is closed
You just have to change the junctions to point to a different folder for each account. Downside is that this way You can only run one account at a time. If You want to run two account simultaneously You'll end up with the EVE client writing to the same folders anyway. But then it shouldnt really be a problem since the player / character settings are saved separately in those .dat files in the settings folder.
|
Ladyah Liandri
VMF-214 Blacksheep
|
Posted - 2007.06.21 11:10:00 -
[6]
Nice work!
There's a maybe simpler way though:
1. Move the content of the folder Eve (folders capture and logs) from your personal folder back to your Eve installation folder.
2. Delete the folder Eve from your personal folder.
3. Create a shortcut of your Eve installation folder.
4. Move that shortcut to your personal folder.
5. Rename that shortcut "eve"
Done.
|
Kristie
Sebiestor tribe
|
Posted - 2007.06.21 11:25:00 -
[7]
Doesn't this only apply to NTFS drives though? I don't know why anyone would willingly have an NTFS system drive, as repairing NTFS HDs is next to impossible. Heck even reading one in DOS can be a chore. But anyways I am 99% sure you cannot junction anything but a NTFS partition.
Kristie |
Robo Jaws
Caldari
Piersons's Products
|
Posted - 2007.06.21 12:21:00 -
[8]
OR yo can take a moment to read the patch notes where you will find this.
IMPORTANT! When the patch has been deployed, your client(s) patched and you log in for the first time, the cache folder will migrate to the new location specified below. Depending on the size of your cache folder, this may be hardly noticeable, it may take several minutes. Please be patient while this happens and do NOT restart your client if it appears to 'hang'! Thank you.
Game capture, log and cache folders have moved from "C:\Program Files\CCP\EVE"
* The capture and logs folders are now located under "My Documents\EVE"
* The settings and cache folder are stored under
o Windows 2000/XP: "C:\Documents and Settings\%username%\Local Settings\Application Data\CCP\EVE"
o Windows Vista: "C:\Users\%user%\AppData\Local\CCP\EVE"
The location of the settings folder can be forced to remain where it was stored prior to Revelations II. This can be useful when connecting a second client to a test server and not mix settings between the clients.
* If the user choses to revert to this storage format, the shortcut needs to be modified to refer to: "C:\Program Files\CCP\EVE\eve.exe /end /LUA:OFF". Note the switches (/end and /LUA:OFF) are case sensitive.
|
Caliera
|
Posted - 2007.06.21 15:27:00 -
[9]
Edited by: Caliera on 21/06/2007 15:30:22
True, junctioning only works on NTFS formatted drives.
And regarding the switches "/end and /LUA:OFF" - Unfortunately it looks like there will still be some files written to the C drive even if they're set. If only the settings folder is reverted back to the pre Rev2 location all the logfiles, and other stuff will still land in "my documents\eve\logs".
Reads: "The location of the settings folder can be forced to remain where it was stored prior to Revelations II. This can be useful when connecting a second client to a test server and not mix settings between the clients."
|
Caliera
|
Posted - 2007.06.22 15:14:00 -
[10]
...bumping this one up again since it looks like some people could really profit from it.
|
| |
|
| Pages: [1] :: one page |
| First page | Previous page | Next page | Last page |